!!! Plošný model struktury A pro lineární úlohu při zatížení ve směru osy y !!!

FINISH
/CLEAR

*ABBR,INPUT,'/INPUT,strukturaA_linear_Y,txt'   

/PREP7

*DO,step,55,90,5		! cyklus pro automaticky vypocet

*AFUN,RAD            
 PI=4*ATAN(1)        	! vypocet hodnoty PI
*AFUN,DEG            

!!!!!!!!!!!!!!!!!!!
!!! PREPROCESOR !!!
!!!!!!!!!!!!!!!!!!!           

/PREP7

!!! Vstupni parametry !!!
alfa=step				! uhel alfa	[°]			
H=10					! delka H [mm]
LH=1.25					! pomer L/H [-]				
p=0.75					! porozita [-]
Emod=200000				! modul pruznosti v tahu zakladniho materialu [MPa]
nu=0.3					! Poissonuv pomer zakladniho materialu [-]
Fappl=-1				! zatezna sila [N]
ELSIZE=0.5				! velikost prvku [mm]


L=LH*H					! automaticke nastaveni potrebnych parametru
SELTOL,1e-6
p=1-p
TH=1

!!! Urceni tloustky pri zadane porozite !!!
*AFUN,RAD 
alfa=alfa*PI/180	!rad

ODM111=-0.3125*LH**2*P*cos(alfa)
ODM11=0.25*LH**2*p*(cos(alfa))**2+ODM111

ODM121=0.25*LH**2*cos(alfa)-0.25*LH**2
ODM12=0.0625*LH**2*P*cos(3*alfa)+ODM121

ODM1=ODM11+ODM12

ODM21=0.5*LH*cos(alfa)-0.5*LH+0.25*cos(alfa)-0.25
ODM22=-0.5*LH*p*cos(alfa)+LH*p
ODM2=-0.5*LH*P*(cos(alfa))**2+ODM22+ODM21

ODM=1.4142135623731*sqrt(-(ODM1+ODM2)*(tan(0.5*alfa))**2)*cos(0.5*alfa)

cast1=LH*(sin(0.5*alfa))**2

cast2=(sin(0.5*alfa))**2

jmenovatel=(cos(alfa))**2+cos(alfa)-2

T=-(4*H*(cast1-ODM+cast2)*sin(alfa))/jmenovatel		! vysledna tloustka

*AFUN,DEG  
alfa=alfa*180/pi


!!! Definice elementu !!!
ET,1,PLANE183

!!! Definice materialu !!!
MP,EX,1,Emod
MP,PRXY,1,,nu

!!! Tvorba geometrie !!!
	
	!!! Referencni geometrie !!!
K,10,H-L*cos(alfa),0,0
K,20,H,L*sin(alfa),0
K,30,0,L*sin(alfa),0

!L,10,20	$	L,20,30

	!!! Vnitrni geometrie !!!
K,1,H-L*cos(alfa)-T/(2*cos(90-alfa)),0,0
K,2,H-T/2*(cos(alfa/2)/sin(alfa/2)),L*sin(alfa)-T/2,0
K,3,0,L*sin(alfa)-T/2,0

L,1,2	$	L,2,3	

	!!! Vnejsi geometrie !!!
!K,11,H-L*cos(alfa)+T/(2*cos(90-alfa)),0,0
K,11,H-L*cos(alfa)+T/(2*tan(alfa/2)),T/2,0
K,22,H+T/2*(cos(alfa/2)/sin(alfa/2))-T/2*tan(90-alfa),L*sin(alfa),0
K,33,0,L*sin(alfa),0
K,111,H-L*cos(alfa),0,0
K,41,2*H-L*cos(alfa),T/2,0
K,44,2*H-L*cos(alfa),0,0

L,11,22	$	L,22,33	$	

L,1,111	$	L,111,44	$	L,44,41	$	L,41,11	$	L,3,33

!!! Vyjadreni obsahu !!!
SA=(2*H-L*cos(alfa))*L*sin(alfa)
S1=(H-L*cos(alfa)-T/(2*cos(90-alfa)))*(L*sin(alfa)-T/2)
S2=((H-T/2*(cos(alfa/2)/sin(alfa/2)))-(H-L*cos(alfa)-T/(2*cos(90-alfa))))*(L*sin(alfa)-T/2)*0.5
S3=((H+T/2*(cos(alfa/2)/sin(alfa/2))-T/2*tan(90-alfa))-(H-L*cos(alfa)+T/(2*tan(alfa/2))))*(L*sin(alfa)-T/2)*0.5
S4=((2*H-L*cos(alfa))-(H+T/2*(cos(alfa/2)/sin(alfa/2))-T/2*tan(90-alfa)))*(L*sin(alfa)-T/2)

S=SA-(S1+S2+S3+S4)


	!!! Vytvoreni plochy !!!
LSEL,ALL
AL,ALL

!!! Vytvoreni site !!!
ASEL,ALL
ESIZE,ELSIZE
AATT,1,,1
AMESH,ALL

!!! Okrajove podminky !!!
NSEL,S,LOC,Y,L*sin(alfa)				$	CP,1,UY,ALL			
NSEL,S,LOC,Y,0							$	D,ALL,UY,0	
NSEL,S,LOC,X,0							$	D,ALL,UX,0
NSEL,S,LOC,X,2*H-L*cos(alfa)			$	CP,2,UX,ALL

ALLSEL,ALL

!!! Zatizeni !!!
NSEL,S,LOC,Y,L*sin(alfa)	$	NSEL,R,LOC,X,0
F,ALL,FY,Fappl/2

ALLSEL,ALL


!!!!!!!!!!!!!!!!
!!! SOLUTION !!!
!!!!!!!!!!!!!!!!

/SOLU


SOLVE


!!!!!!!!!!!!!!!!!!!!!
!!! POSTPROCESSOR !!!
!!!!!!!!!!!!!!!!!!!!!

/POST1

!!! Zjisteni posuvu ve smeru x !!!
NSEL,S,LOC,X,2*H-L*cos(alfa)	$	NSEL,R,LOC,Y,0	
*GET,minnode1,NODE,0,NUM,MIN
*GET,UXdisp,NODE,minnode1,U,X

!!! Zjisteni posuvu ve smeru y !!!
NSEL,S,LOC,X,0	$	NSEL,R,LOC,Y,L*sin(alfa)	
*GET,minnode3,NODE,0,NUM,MIN
*GET,UYdisp,NODE,minnode3,U,Y

!!! Vypocet Poissonova pomeru !!!
X0=2*H-L*cos(alfa)
Y0=L*sin(alfa)

epsX=UXdisp/X0
epsY=UYdisp/Y0

nuCALCyx=-epsX/epsY				! hodnota vysledneho Poissonova pomeru [-]

!!! Urceni plochy bunek !!!
S=(2*H-L*cos(alfa))*TH

!!! Vypocet E !!!
sigma=(Fappl/2)/S
EcalcY=abs(sigma/epsY)/Emod		! hodnota vysledneho pomerneho modulu pruznosti v tahu [-]

!!! Kontrola dotyku vnitrních rohu !!!
kontrola_dotyku=H-L*cos(alfa)-T/(2*cos(90-alfa))		! musi byt kladne cislo

!!! Kontrola tloustky !!!
kontrola_tloustky=L*sin(alfa)-1*T			! musi byt kladne cislo


!!!					!!!
!!! Export vysledku !!!
!!!					!!!

*CFOPEN,nuCALCyx,txt,,APPEND
*VWRITE,nuCALCyx
(1F12.6)
*CFCLOS

*CFOPEN,EcalcY,txt,,APPEND
*VWRITE,EcalcY
(1F12.10)
*CFCLOS

*CFOPEN,alfa,txt,,APPEND
*VWRITE,alfa
(F10.3)
*CFCLOS

*CFOPEN,kontrola_dotyku,txt,,APPEND
*VWRITE,kontrola_dotyku
(F12.8)
*CFCLOS

*CFOPEN,kontrola_tloustky,txt,,APPEND
*VWRITE,kontrola_tloustky
(F12.8)
*CFCLOS


/CLEAR

*ENDDO

*ABBR,INPUT,'/INPUT,strukturaA_linear_Y,txt' 